;; ----------------------- Initialization -------------------------
patches-own [conversation content content-id content-motivation content-ideology content-party content-availability ]  
            ;; spaces are either in a conversation space (1) or not (0) 
            ;; spaces either content content (1) or not (0)
            ;; content is tagged to match the id and motivation type of the author
            ;; content is published with an ideology (-1,0,1) and party affiliation (0,1,2)
turtles-own [motivation ideology party availability energy collaboration-min collaboration-max] 
            ;; agents have the following properties:
            ;;	motivation - motivation to continue is based on progress (1), identity (2) or mutuality (3)
            ;;	ideology - can be liberal (-1), moderate (0) or conservative (1)
            ;;	party - can be independent (0), progressive (1) or constitutionalist (2)
            ;;	availability - expected level of participation is brief (1), casual (2) or devoted (3)
            ;;	energy - a scale from 0 to 100
            ;;	collaboration-min - the minimum number of agents in conversation space required to participate
            ;;	collaboration-max - the maximum number of agents in conversation space allowed for participation
breeds [Singular Loyalist Connector]     
            ;; agents are one of the following:
            ;;	Singular - attracted to conversation due to personal compatibility with issue topic
            ;;	Loyalist - attracted to conversation due to affinity with group identity
            ;;	Conector - attracted to conversation due to presence of active others
            
globals [ iterations view-type all-turtles ideology-turtles liberal-turtles conservative-turtles party-turtles progressive-turtles constitutionalist-turtles COLOR-1 COLOR-2 COLOR-3 ]


to setup                        ;; setting up the simulation
  set-parameters                ;; use presets to set simulation values
  ca                            ;; clear world
  set-colors                    ;; set default colors
  set-turtles                 	;; distribute agents
  set-patches                 	;; create conversation space
end


to set-colors
  ;; Default Colors
  set COLOR-1 red
  set COLOR-2 blue
  set COLOR-3 gray
end

to set-parameters
  if (Presets = "Standard")
  [
    set numSingular 33          ;; 33 Single Issue agents are included in population
    set numLoyalist 33          ;; 33 Group Loyalist agents are included in population
    set numConnector 33         ;; 33 Connector agents are included in population
    set ideologylevel .67       ;; % of agents who are not Moderate
    set partyaffiliation .67    ;; % of agents who are not Independent
    set ideologybalance .50     ;; % of liberals among agents who are not Moderate
    set partybalance .50        ;; % of progressives among agents who are not Independent

    set numspaces 1             ;; the minium number of forums are created
    set awareness 1             ;; the radius of awareness around new content is MINIMIZED
    set decay-rate 0            ;; time-sensitivity of interaction is turned off

    set EnergySap false         ;; activity requirement for publication turned off
    set availabilitylevel 1     ;; % of agents who are Devoted contributors (1/3 of others are Casual)

    set identity 0              ;; motivation requirement for Loyalists turned off
    set mutuality 0             ;; motivation requirement for Connectors turned off
  ]
  if (Presets = "Time-Sensitive")
  [
    set numSingular 33          ;; 33 Single Issue agents are included in population
    set numLoyalist 33          ;; 33 Group Loyalist agents are included in population
    set numConnector 33         ;; 33 Connector agents are included in population
    set ideologylevel .67       ;; % of agents who are not Moderate
    set partyaffiliation .67    ;; % of agents who are not Independent
    set ideologybalance .50     ;; % of liberals among agents who are not Moderate
    set partybalance .50        ;; % of progressives among agents who are not Independent

    set numspaces 1             ;; the minium number of forums are created
    set awareness 5             ;; the radius of awareness around new content is 5 patches
    set decay-rate 25           ;; time-sensitivity of interaction is MAXIMIZED

    set EnergySap false         ;; activity requirement for publication turned off
    set availabilitylevel 1     ;; % of agents who are Devoted contributors (1/3 of others are Casual)

    set identity 0              ;; motivation requirement for Loyalists turned off
    set mutuality 0             ;; motivation requirement for Connectors turned off
  ]
  if (Presets = "With Motivation")
  [
    set numSingular 33          ;; 33 Single Issue agents are included in population
    set numLoyalist 33          ;; 33 Group Loyalist agents are included in population
    set numConnector 33         ;; 33 Connector agents are included in population
    set ideologylevel .67       ;; % of agents who are not Moderate
    set partyaffiliation .67    ;; % of agents who are not Independent
    set ideologybalance .50     ;; % of liberals among agents who are not Moderate
    set partybalance .50        ;; % of progressives among agents who are not Independent

    set numspaces 1             ;; the minium number of forums are created
    set awareness 5             ;; the radius of awareness around new content is 5 patches
    set decay-rate 25           ;; time-sensitivity of interaction is turned off

    set EnergySap false         ;; activity requirement for publication turned off
    set availabilitylevel 1     ;; % of agents who are Devoted contributors (1/3 of others are Casual)

    set identity 2              ;; motivation requirement for Loyalists TURNED ON (at least 2 nearby same-party content)
    set mutuality 1             ;; motivation requirement for Connectors TURNED ON (at least one nearby agent)
  ]
  if (Presets = "With Availability")
  [
    set numSingular 33          ;; 33 Single Issue agents are included in population
    set numLoyalist 33          ;; 33 Group Loyalist agents are included in population
    set numConnector 33         ;; 33 Connector agents are included in population
    set ideologylevel .67       ;; % of agents who are not Moderate
    set partyaffiliation .67    ;; % of agents who are not Independent
    set ideologybalance .50     ;; % of liberals among agents who are not Moderate
    set partybalance .50        ;; % of progressives among agents who are not Independent

    set numspaces 1             ;; the minium number of forums are created
    set awareness 6             ;; the radius of awareness around new content is 6 PATCHES
    set decay-rate 25           ;; time-sensitivity of interaction is MAXIMIZED

    set EnergySap true          ;; activity requirement for publication TURNED ON
    set availabilitylevel .1    ;; % of agents who are Devoted contributors (1/3 of others are Casual)

    set identity 0              ;; motivation requirement for Loyalists turned off
    set mutuality 0             ;; motivation requirement for Connectors turned off
  ]
  if (Presets = "Multi-Forum")
  [
    set numSingular 33          ;; 33 Single Issue agents are included in population
    set numLoyalist 33          ;; 33 Group Loyalist agents are included in population
    set numConnector 33         ;; 33 Connector agents are included in population
    set ideologylevel .67       ;; % of agents who are not Moderate
    set partyaffiliation .67    ;; % of agents who are not Independent
    set ideologybalance .50     ;; % of liberals among agents who are not Moderate
    set partybalance .50        ;; % of progressives among agents who are not Independent

    set numspaces 5             ;; 5 FORUMS are created
    set awareness 5             ;; the radius of awareness around new content is 5 patches
    set decay-rate 25           ;; time-sensitivity of interaction is MAXIMIZED

    set EnergySap false         ;; activity requirement for publication turned off
    set availabilitylevel 1     ;; % of agents who are Devoted contributors (1/3 of others are Casual)

    set identity 0              ;; motivation requirement for Loyalists turned off
    set mutuality 0             ;; motivation requirement for Connectors turned off
  ]
end

;; ----------------------- Agent setup -------------------------
  
to set-turtles					        ;; setup the agent population
  create-custom-Singular numSingular     
  [ set motivation 1 			      ;; make selected agents attracted to personal issues
	  set shape "triangle" ]
  create-custom-Loyalist numLoyalist 
  [ set motivation 2 			      ;; make selected agents attracted to group identity
	  set shape "square" ]
  create-custom-Connector numConnector 
  [ set motivation 3 			      ;; make selected agents attracted to mutual connection
	  set shape "circle" ]
	  
  ask turtles                    
  [ 
    set energy 1 
    set collaboration-min 0 
    set collaboration-max 1000 

    set ideology 0 
    set party 0 
    set availability 1 
    set color COLOR-3
    
    fd (random screen-edge-x)	  ;; moves turtles from initial location at center randomly
  ]          

  ;; Distribute other properties randomly
  set all-turtles count turtles
  
	;; IDEOLOGY
	ask random-n-of ((all-turtles * ideologylevel) * ideologybalance) turtles
  [ set ideology -1 		        ;; make selected agents LIBERAL
    set color COLOR-1 ]
	ask random-n-of ((all-turtles * ideologylevel) - ((all-turtles * ideologylevel) * ideologybalance)) turtles with [ ideology = 0 ]
  [ set ideology 1 		          ;; make selected agents CONSERVATIVE
    set color COLOR-2 ]
  
  ;; PARTY AFFILIATION  
	ask random-n-of ((all-turtles * partyaffiliation) * partybalance) turtles
  [ set party 1 ]		            ;; make selected agents PROGRESSIVE
	ask random-n-of ((all-turtles * partyaffiliation) - ((all-turtles * partyaffiliation) * partybalance)) turtles with [ party = 0 ]
  [ set party 2 ]		            ;; make selected agents CONSTITUTIONALIST
  
  ;; AVAILABILITY  
	ask random-n-of (all-turtles * availabilitylevel) turtles
  [ set availability 3 ]		    ;; make selected agents DEVOTED
	ask random-n-of ((all-turtles - (count turtles with [availability = 3])) * .33) turtles with [ availability = 1 ]
  [ set availability 2 ]		    ;; make selected agents CASUAL
	
end


;; ----------------------- World setup -------------------------

to set-patches					        ;; mark cells as converation spaces or not, called by setup and when resetting converation spaces
  set view-type "Ideology"
  ask patches                   ;; initialize spaces as not conversation spaces
    [ set conversation 0 
      set content 0 
      set content-id -1
      set pcolor black ]
  repeat numspaces              ;; make the selected number of conversation spaces
    [ setup-conversation ] 
  ask patches                   ;; mark conversation spaces as such
    [ if (conversation > 0) 
      [ set pcolor white ] 
	    if (content = 1) 
      [ ifelse (content-ideology < 0)
			  [ set pcolor COLOR-1 ]     ;; LIBERAL
			  [ ifelse (content-ideology > 0)
			    [ set pcolor COLOR-2 ]   ;; CONSERVATIVE
			    [ set pcolor COLOR-3 ]   ;; MODERATE
    ] ] ] 
end

to setup-conversation
  ask random-one-of turtles
  [ ask patches in-radius awareness
    [ set conversation 1 ]      ;; mark conversation space
    set content 1 			        ;; center of conversation space has content
	  set content-id who 
	  set content-motivation motivation 
	  set content-ideology ideology 
		set content-party party 
		set content-availability availability
	] 
end


;; ----------------------- Run simulation -------------------------

to go
;;  if (count patches with [conversation = 1] = 0) [ stop ]
  keep-count                    ;; keep track of iterations in simulation
  move-turtles					        ;; agents move, some create content
  decay-conversation            ;; allow conversation to decline
  publish-content					      ;; find content with nearby turtles able to publish
  do-plots
  turtle-visibility             ;; hide/show agents
end


to keep-count
  set iterations (iterations + 1)
end


to move-turtles
  ask turtles [
  	set heading (random 360)	  ;; Move agent in random direction 
	  fd 1 
  ]
end


to decay-conversation
  if (decay-rate > 0) and ((iterations / 3) mod (26 - decay-rate) = 0)
  [ ;; reduce conversation space
    ask patches with [sum values-from neighbors [conversation] < 7]
    [
  	  set conversation 0
  	  if (pcolor = white) [ set pcolor black ] 
    ] 
    ;; reduce agent energy, if outside conversation space (except Devoted)
    ask turtles with [ (energy > 0) and (availability < 3) and (conversation = 0) ]
    [
      set energy (energy - .01)
    ] 
    ;; increase agent energy, if inside conversation space (Casual only)
    ask turtles with [ (energy < 1) and (availability = 2 ) and (conversation = 1) ]
    [
      set energy (energy + .01)
  ] ]
end


to publish-content
  ;; find all potential authors
  ask turtles with [ any? neighbors with [ content = 1 and conversation = 1 ] and (not EnergySap or energy > 0) ]
  [ ;; copy author profile
    let this-id who
    let this-motivation motivation
    let this-ideology ideology
    let this-party party
    let this-availability availability
    let this-energy energy
    
    let thread-candidates neighbors with [ 
      (content = 1 and content-id != this-id) 
      and
      (this-motivation != 2 or count neighbors with [ content-party = this-party ] >= identity)
      and
      (this-motivation != 3 or count neighbors with [ any? turtles-here ] >= mutuality)
      ]
    if any? thread-candidates
    [ ;; publish new content
      set content 1 
	    set content-id this-id
	    set content-motivation this-motivation
	    set content-ideology this-ideology
	    set content-party this-party
	    set content-availability this-availability
	    
	    if (view-type = "Ideology")
	    [ ;; IDEOLOGY
	      if (this-ideology = -1) [ set pcolor COLOR-1 ]    ;; LIBERAL
	      if (this-ideology = 1) [ set pcolor COLOR-2 ]     ;; CONSERVATIVE
	      if (this-ideology = 0) [ set pcolor COLOR-3 ]     ;; MODERATE
	    ]
	    if (view-type = "Party")
	    [ ;; PARTY AFFILIATION
	      if (this-party = 1) [ set pcolor COLOR-1 ]        ;; PROGRESSIVE
	      if (this-party = 2) [ set pcolor COLOR-2 ]        ;; CONSTITUTIONALIST
	      if (this-party = 0) [ set pcolor COLOR-3 ]        ;; INDEPENDENT
	    ]
	    if (view-type = "Motivation")
	    [ ;; MOTIVATION TO PUBLISH
	      if (this-motivation = 1) [ set pcolor COLOR-1 ]   ;; PROGRESS
	      if (this-motivation = 2) [ set pcolor COLOR-2 ]   ;; IDENTITY
	      if (this-motivation = 3) [ set pcolor COLOR-3 ]   ;; MUTUALITY
	    ]
	    if (view-type = "Availability")
	    [ ;; AVAILABILITY TO PUBLISH
	      if (this-availability = 1) [ set pcolor COLOR-1 ] ;; BRIEF
	      if (this-availability = 2) [ set pcolor COLOR-2 ] ;; CASUAL
	      if (this-availability = 3) [ set pcolor COLOR-3 ] ;; DEVOTED
	    ]

      ;; expand conversation space around new content
      ask patches in-radius awareness 
        [ set conversation 1   ;; mark conversation space
          if (content = 0) [ set pcolor white ]
	    ]  
	  ]
  ]
end


to view-selection [viewType]
  set view-type viewType
  if (viewType = "Ideology")
  [ ;; change color scheme
    set COLOR-1 red
    set COLOR-2 blue
    set COLOR-3 gray

    ask patches with [content = 1]    ;; change content to reflect Ideology
    [ 
      if (content-ideology = -1) [ set pcolor COLOR-1 ]  ;; LIBERAL
	    if (content-ideology = 1) [ set pcolor COLOR-2 ]   ;; CONSERVATIVE
	    if (content-ideology = 0) [ set pcolor COLOR-3 ]   ;; MODERATE
    ]
    ask turtles                       ;; change turtles to show Ideology
    [ 
      if (ideology = -1) [ set color COLOR-1 ]           ;; LIBERAL
	    if (ideology = 1) [ set color COLOR-2 ]            ;; CONSERVATIVE
	    if (ideology = 0) [ set color COLOR-3 ]            ;; MODERATE
    ]
  ]

  if (viewType = "Party")
  [ ;; change color scheme
    set COLOR-1 green
    set COLOR-2 yellow
    set COLOR-3 gray

    ask patches with [content = 1]    ;; change content to reflect Party
    [ 
      if (content-party = 1) [ set pcolor COLOR-1 ]     ;; PROGRESSIVE
	    if (content-party = 2) [ set pcolor COLOR-2 ]     ;; CONSTITUTIONALIST
	    if (content-party = 0) [ set pcolor COLOR-3 ]     ;; MODERATE
    ]
    ask turtles                       ;; change turtles to show Party
    [ 
      if (party = 1) [ set color COLOR-1 ]              ;; PROGRESSIVE
	    if (party = 2) [ set color COLOR-2 ]              ;; CONSTITUTIONALIST
	    if (party = 0) [ set color COLOR-3 ]              ;; MODERATE
    ]
  ]
  
  if (viewType = "Motivation")
  [ ;; change color scheme
    set COLOR-1 brown
    set COLOR-2 orange
    set COLOR-3 violet

    ask patches with [content = 1]    ;; change content to reflect Motivation
    [ 
	    if (content-motivation = 1) [ set pcolor COLOR-1 ] ;; PROGRESS
	    if (content-motivation = 2) [ set pcolor COLOR-2 ] ;; IDENTITY
	    if (content-motivation = 3) [ set pcolor COLOR-3 ] ;; MUTUALITY
    ]
    ask turtles                       ;; change turtles to show Motivation
    [ 
	    if (motivation = 1) [ set color COLOR-1 ]          ;; PROGRESS
	    if (motivation = 2) [ set color COLOR-2 ]          ;; IDENTITY
	    if (motivation = 3) [ set color COLOR-3 ]          ;; MUTUALITY
    ]
  ]
  
  if (viewType = "Availability")
  [ ;; change color scheme
    set COLOR-1 cyan
    set COLOR-2 turquoise
    set COLOR-3 sky

    ask patches with [content = 1]    ;; change content to reflect Availability
    [ 
	    if (content-availability = 1) [ set pcolor COLOR-1 ] ;; BRIEF
	    if (content-availability = 2) [ set pcolor COLOR-2 ] ;; CASUAL
	    if (content-availability = 3) [ set pcolor COLOR-3 ] ;; DEVOTED
    ]
    ask turtles                       ;; change turtles to show Availability
    [ 
	    if (availability = 1) [ set color COLOR-1 ]          ;; BRIEF
	    if (availability = 2) [ set color COLOR-2 ]          ;; CASUAL
	    if (availability = 3) [ set color COLOR-3 ]          ;; DEVOTED
    ]
  ]
end


to turtle-visibility 
  ask turtles 
    [ 
      ifelse (showTurtles = true)
      [ st ]
      [ ht ]
    ]
end

to do-plots      
    
  set-current-plot "Conversation Space" 
  if (count patches > 0)
  [ set-current-plot-pen "% Conversation" 
    plot count patches with [conversation = 1] / count patches 
    set-current-plot-pen "% Content"   
    plot count patches with [content = 1] / count patches 
  ]
  if (count patches with [conversation = 1] > 0)
  [ set-current-plot-pen "Membership"
    plot count turtles with [conversation = 1] / count patches with [conversation = 1] 
    set-current-plot-pen "Production"
    plot count patches with [content = 1] / count patches with [conversation = 1]
  ]

end



@#$#@#$#@
GRAPHICS-WINDOW
385
10
953
647
46
50
6.0
1
10
1
1
1
0
1
1
1

CC-WINDOW
5
862
1357
957
Command Center
0

BUTTON
6
10
87
55
New World
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
172
10
253
55
GO
go
T
1
T
OBSERVER
T
NIL

SLIDER
12
815
157
848
numConnector
numConnector
0
100
33
1
1
NIL

SLIDER
12
741
157
774
numSingular
numSingular
0
100
33
1
1
NIL

SLIDER
12
778
157
811
numLoyalist
numLoyalist
0
100
33
1
1
NIL

BUTTON
89
10
170
55
Relocate
set-patches
NIL
1
T
OBSERVER
T
NIL

SLIDER
168
814
274
847
numspaces
numspaces
1
10
1
1
1
NIL

SLIDER
168
742
355
775
awareness
awareness
1
25
5
1
1
NIL

SLIDER
375
778
562
811
ideologybalance
ideologybalance
0
1
0.5
0.01
1
NIL

SLIDER
375
742
562
775
ideologylevel
ideologylevel
0
1
0.67
0.01
1
NIL

SLIDER
566
742
753
775
partyaffiliation
partyaffiliation
0
1
0.67
0.01
1
NIL

SLIDER
566
778
754
811
partybalance
partybalance
0
1
0.5
0.01
1
NIL

MONITOR
12
403
103
452
LIBERAL
count turtles with [ideology < 0] / count turtles
2
1

MONITOR
12
505
103
554
MODERATE
count turtles with [ideology = 0] / count turtles
2
1

MONITOR
12
454
103
503
CONSERVATIVE
count turtles with [ideology > 0] / count turtles
2
1

MONITOR
106
505
215
554
INDEPENDENT
count turtles with [party = 0] / count turtles
2
1

MONITOR
105
403
215
452
PROGRESSIVE
count turtles with [party = 1] / count turtles
2
1

MONITOR
105
454
215
503
CONSTITUTIONALIST
count turtles with [party = 2] / count turtles
2
1

MONITOR
12
575
102
624
LIBERAL
count patches with [content-ideology < 0 and content = 1] / count patches with [content = 1]
2
1

MONITOR
12
626
102
675
CONSERVATIVE
count patches with [content-ideology > 0 and content = 1] / count patches with [content = 1]
2
1

MONITOR
12
677
102
726
MODERATE
count patches with [content-ideology = 0 and content = 1] / count patches with [content = 1] 
2
1

TEXTBOX
13
557
100
575
CONTENT

MONITOR
105
677
215
726
INDEPENDENT
count patches with [content-party = 0 and content = 1] / count patches with [content = 1]
2
1

MONITOR
105
575
215
624
PROGRESSIVE
count patches with [content-party = 1 and content = 1] / count patches with [content = 1]
2
1

MONITOR
105
626
215
675
CONSTITUTIONALIST
count patches with [content-party = 2 and content = 1] / count patches with [content = 1]
2
1

MONITOR
218
575
290
624
PROGRESS
count patches with [content-motivation = 1 and content = 1] / count patches with [content = 1]
2
1

MONITOR
218
626
290
675
IDENTITY
count patches with [content-motivation = 2 and content = 1] / count patches with [content = 1]
2
1

MONITOR
218
677
290
726
MUTUALITY
count patches with [content-motivation = 3 and content = 1] / count patches with [content = 1]
2
1

BUTTON
218
348
290
381
Motivation
view-selection ("Motivation")
NIL
1
T
OBSERVER
T
NIL

BUTTON
12
348
102
381
Ideology
view-selection ("Ideology")
NIL
1
T
OBSERVER
T
NIL

BUTTON
105
348
215
381
Party
view-selection ("Party")
NIL
1
T
OBSERVER
T
NIL

SWITCH
273
57
382
90
ShowTurtles
ShowTurtles
0
1
-1000

SLIDER
168
777
355
810
decay-rate
decay-rate
0
25
25
1
1
NIL

CHOOSER
148
180
250
225
mutuality
mutuality
0 1 2 3 4
1

CHOOSER
254
180
356
225
identity
identity
0 1 2 3 4 5 6 7 8 9
2

MONITOR
386
674
460
723
View Type
view-type
0
1

MONITOR
293
403
355
452
BRIEF
count turtles with [availability = 1] / count turtles
2
1

OUTPUT
463
673
950
723

TEXTBOX
16
384
166
402
AGENTS

MONITOR
293
454
355
503
CASUAL
count turtles with [availability = 2] / count turtles
2
1

MONITOR
293
505
355
554
DEVOTED
count turtles with [availability = 3] / count turtles
2
1

MONITOR
218
403
290
452
PROGRESS
count turtles with [motivation = 1] / count turtles
2
1

MONITOR
218
454
290
503
IDENTITY
count turtles with [motivation = 2] / count turtles
2
1

MONITOR
218
505
290
554
MUTUALITY
count turtles with [motivation = 3] / count turtles
2
1

BUTTON
293
348
355
381
Availability
view-selection ("Availability")
NIL
1
T
OBSERVER
T
NIL

MONITOR
293
575
355
624
BRIEF
count patches with [content-availability = 1 and content = 1] / count patches with [content = 1]
2
1

MONITOR
293
626
355
675
CASUAL
count patches with [content-availability = 2 and content = 1] / count patches with [content = 1]
2
1

MONITOR
293
677
355
726
DEVOTED
count patches with [content-availability = 3 and content = 1] / count patches with [content = 1]
2
1

SLIDER
757
742
945
775
availabilitylevel
availabilitylevel
0
1
0.1
0.01
1
NIL

SWITCH
32
185
134
218
EnergySap
EnergySap
0
1
-1000

MONITOR
173
59
253
108
Energy
sum values-from turtles [energy] / count turtles
3
1

MONITOR
90
110
170
159
Conversation
count patches with [conversation = 1] / count patches
3
1

CHOOSER
273
10
382
55
Presets
Presets
"Custom" "Standard" "Time-Sensitive" "With Motivation" "With Availability" "Multi-Forum"
0

MONITOR
6
59
87
108
Population
count turtles / count patches
3
1

MONITOR
90
59
170
108
Members
count turtles with [conversation = 1] / count patches with [conversation = 1]
3
1

MONITOR
6
110
87
159
Content
count patches with [content = 1] / count patches
3
1

MONITOR
173
110
253
159
Publish Density
count patches with [content = 1] / count patches with [conversation = 1] \n
3
1

PLOT
974
10
1348
646
Conversation Space
Iterations
NIL
0.0
100.0
0.0
1.0
true
false
PENS
"% Conversation" 1.0 0 -16777216 true
"% Content" 1.0 0 -13345367 true
"Membership" 1.0 0 -10899396 true
"Production" 1.0 0 -5825686 true

@#$#@#$#@
WHAT IS IT?
-----------
This section could give a general understanding of what the model is trying to show or explain.


HOW IT WORKS
------------
This section could explain what rules the agents use to create the overall behavior of the model.


HOW TO USE IT
-------------
This section could explain how to use the model, including a description of each of the items in the interface tab.


THINGS TO NOTICE
----------------
This section could give some ideas of things for the user to notice while running the model.


THINGS TO TRY
-------------
This section could give some ideas of things for the user to try to do (move sliders, switches, etc.) with the model.


EXTENDING THE MODEL
-------------------
This section could give some ideas of things to add or change in the procedures tab to make the model more complicated, detailed, accurate, etc.


NETLOGO FEATURES
----------------
This section could point out any especially interesting or unusual features of NetLogo that the model makes use of, particularly in the Procedures tab.  It might also point out places where workarounds were needed because of missing features.


RELATED MODELS
--------------
This section could give the names of models in the NetLogo Models Library or elsewhere which are of related interest.


CREDITS AND REFERENCES
----------------------
This section could contain a reference to the model's URL on the web if it has one, as well as any other necessary credits or references.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.0.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@